[問題] 如何建立SWF檔

[bruce620 (o(‧"‧)o)]

請教一個基本的問題 @_@?

就是我在看Flash Action Script 3.0 動畫製作大師一書時

書中寫到

務必確認Arrow.as檔是跟RotateToMouse.as檔放在同一個目錄裡，

而且是用RotateToMouse文件類別建立SWF檔。

而書中的範例檔案只有提供.as的檔

裡面Arrow.as開起的程式是

package {
        import flash.display.Sprite;

        public class Arrow extends Sprite {
                public function Arrow() {
                        init();
                }
                public function init():void {
                        graphics.lineStyle(1, 0, 1);
                        graphics.beginFill(0xffff00);
                        graphics.moveTo(-50, -25);
                        graphics.lineTo(0, -25);
                        graphics.lineTo(0, -50);
                        graphics.lineTo(50, 0);
                        graphics.lineTo(0, 50);
                        graphics.lineTo(0, 25);
                        graphics.lineTo(-50, 25);
                        graphics.lineTo(-50, -25);
                        graphics.endFill();
                }
        }
}

而RotateToMouse.as所開啟的程式碼是

package
{
        import flash.display.Sprite;
        import flash.events.Event;

        public class RotateToMouse extends Sprite {
                private var arrow:Arrow;

                public function RotateToMouse() {
                        init();
                }
                private function init():void {
                        arrow = new Arrow();
                        addChild(arrow);
                        arrow.x = stage.stageWidth / 2;
                        arrow.y = stage.stageHeight / 2;
                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                }
                public function onEnterFrame(event:Event):void {
                        var dx:Number = mouseX - arrow.x;
                        var dy:Number = mouseY - arrow.y;
                        var radians:Number = Math.atan2(dy, dx);
                        arrow.rotation = radians * 180 / Math.PI;
                }
        }
}

只有提供.as檔

請教要如何將這些.as檔發佈成swf檔來預覽呢？

首次學習將as放置到.as裡

但不太了解要怎讓他們發佈成swf

來這請教各位指導一下

謝謝< _ _>


--
※ 發信站: 批踢踢實業坊(ptt.cc) 
◆ From: 220.134.181.103
推 cjcat2266:兩個方法，下載Flex SDK，然後把你的主程式AS檔拖曳到
→ cjcat2266:mxmlc.exe上面放開。第二個方法，存一個FLA在主程式AS的
→ cjcat2266:旁邊，開FLA檔之後，在屬性欄位的document class
→ cjcat2266:填入RotateToClass，之後ctrl+ENTER就可以編譯了
→ bruce620:了解了 學會了 謝謝cjcat大 <_ _>
推 lin884006:高手