※ 引述《vavay (樺樹盛開在我心)》之銘言：
: 軟體:office excel 版本:2007
: 這是我有疑問的 google docs位置 http://tinyurl.com/2capvl
: 就是要統計"工作表2"內的資料
: 1.總計學分、總計時數、開課班數
: 2.專任（人次）、專任學分數(人次)、兼任（人次）、兼任學分數(人次)
: 比較有問題的是2
: 專任（人次）指的是"工作表1"裡面某系（i.g.口腔衛生學系）專任的人次有多少
: 專任（人數）指的是"工作表1"裡面某系（i.g.口腔衛生學系）專任的人數有多少
: （要扣除重覆的人）
: 專任學分數(人次)指的是"工作表1"裡面某系專任教師的學分數總合為多少
: 【如口腔衛生學系裡面專任教任共有15人次，共教了45學分】
: 是不是要用vlookup啊??
: 我搞了好久還是搞不懂
: 有沒有excel的強人大大可以指點我一下 真的感謝啦 Orz....
M N O R S T U V W X
1 系/所 所屬系所 專任 專任 專任 兼任 兼任
（人次）（人數） 學分數 （人次） 學分數
2 系 口腔衛生學系 7 3 11 無此項 2 4
3 系 呼吸治療學系 7 5 17 1 2
不了解為何"專任學分數(人數)"
會有"(人數)"
符合 1.該系的 2.是專任的 學分，就加起來
好像沒有人數 人次之分?
S2
=SUMPRODUCT(($A$3:$A$20=$N3)*($H$3:$H$20="專任"))
T2(陣列公式)
{=SUM(IF(FREQUENCY(IF(LEN(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""))>0,MATCH(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""),IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""),0),""), IF(LEN(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""))>0,MATCH(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""),IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),
$C$3:$C$20,""),0),""))>0,1))}
U2
=SUMPRODUCT(($A$3:$A$20=$N3)*($H$3:$H$20="專任")*$F$3:$F$20)
W2
=SUMPRODUCT(($A$3:$A$20=$N3)*($H$3:$H$20="兼任"))
X2
=SUMPRODUCT(($A$3:$A$20=$N3)*($H$3:$H$20="兼任")*$F$3:$F$20)
專任人數最難，(有條件求不重覆數)
(或許還可以簡化)
其他比較好理解.
http://kuso.cc/countsum
-----
簡化可能如
=SUM(IF(FREQUENCY(IF(LEN(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任
"),$C$3:$C$20,""))>0,MATCH($C$3:$C$20,IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任
"),$C$3:$C$20,""),0),""), IF(LEN(IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任
"),$C$3:$C$20,""))>0,MATCH($C$3:$C$20,IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任
"),$C$3:$C$20,""),0),""))>0,1))
好不到哪裡去
要點：
說明檔裡面有寫到"使用函數計算唯一值的數目"
=SUM(IF(FREQUENCY(IF(LEN(A2:A10)>0,MATCH(A2:A10,A2:A10,0),""),
IF(LEN(A2:A10)>0,MATCH(A2:A10,A2:A10,0),""))>0,1))
計算儲存格 A2:A10 中唯一文字和數值的數目，
但是不將空白儲存格或文字值計算在內 (6)
本題中，只是把其中的A2:A10換成
IF(($A$3:$A$20=$N3)*($H$3:$H$20="專任"),$C$3:$C$20,"")
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 218.164.50.203
※ 編輯: JieJuen 來自: 122.123.37.251 (11/21 04:38)