推 s9009077:感謝大家幫忙 07/17 21:35
→ windknife18:非常詳細 ^_^ 07/17 22:40
※ 編輯: JieJuen 來自: 218.164.49.79 (08/15 18:47)
well, 檢查的這麼詳細應該是很難縮短了 ^^
不過可以避免掉"龘"
(以下有誤 更正於後)
=OFFSET(E5,MATCH(1,SUBTOTAL(3,OFFSET(E5,ROW(1:10)-1,)))-1,)
基本上 此式給出篩選的最後一個結果
=SUM(SUBTOTAL(3,OFFSET(E5,ROW(1:10)-1,)))
計算共篩選出幾個結果
檢查篩選結果是否唯一
=SUM(SUBTOTAL(3,OFFSET(E5,ROW(1:10)-1,)))=SUM(SUBTOTAL(3,OFFSET(E5,ROW(1:10)-1,
))*(E5:E14=OFFSET(E5,MATCH(1,SUBTOTAL(3,OFFSET(E5,ROW(1:10)-1,)))-1,)))
邏輯:"最後一個結果"被篩選出來的個數
是否等於總共篩選出來的個數
因為subtotal沒有countif的參數
所以這種檢查法式子也是很長
再寫的跟w大一樣嚴謹的話 字數應差不多
----
忽然發現原本我的式子有誤
另外，再重寫成比較好改的式子
=OFFSET(E5,MATCH(1,1/SUBTOTAL(3,OFFSET(E5,ROW(1:100)-1,)))-1,)
=IF(SUM(SUBTOTAL(3,OFFSET(E5,ROW(1:100)-1,,1))*(OFFSET(E5,,,100)=OFFSET(E5,
MATCH(1,1/SUBTOTAL(3,OFFSET(E5,ROW(1:100)-1,,1)))-1,)))=SUM(SUBTOTAL(3,
OFFSET(E5,ROW(1:100)-1,,1))),OFFSET(E5,MATCH(1,1/SUBTOTAL(3,OFFSET(E5,
ROW(1:100)-1,,1)))-1,),"")
這兩式應該都是改100就可以變動適用範圍了
※ 引述《windknife18 (windknife18)》之銘言：
: 感覺上要處理這樣的問題，VBA 應該比較容易，請 lka 大寫一個範例給大家參考！
: 如果真的要用公式的話，可以參考以下公式，不過沒有測得很詳細就是了，
: 也沒有試著看能不能寫短一點 ... 看看 J 大有沒有建議囉
: B3
: =IF(ROWS($E$5:$E$100)-SUM(--(IF(SUBTOTAL(3,OFFSET($E$5:$E$100,ROW($E$5:$E$100)
: -MIN(ROW($E$5:$E$100)),,1)),$E$5:$E$100,"")=""))
: -SUM(--(IF(SUBTOTAL(3,OFFSET($E$5:$E$100,ROW($E$5:$E$100)
: -MIN(ROW($E$5:$E$100)),,1)),$E$5:$E$100,"")
: =LOOKUP("龘",IF(SUBTOTAL(3,OFFSET($E$5:$E$100,ROW($E$5:$E$100)
: -MIN(ROW($E$5:$E$100)),,1)),$E$5:$E$100))))>0,"",LOOKUP("龘",
: IF(SUBTOTAL(3,OFFSET($E$5:$E$100,ROW($E$5:$E$100)-MIN(ROW($E$5:$E$100)),,1)),
: $E$5:$E$100)))
: 全部輸入完，記得按 Ctrl+Shift+Enter 結束
: 看看可不可行囉 ^_^
: ※ 引述《s9009077 (企鵝)》之銘言：
: : (若是和其他不同軟體互動之問題 請記得一併填寫)
: : 軟體:excel
: : 版本:2003
: : 如何將要篩選的文字傳到某一儲存格
: : ｅｘ
: : ｘｘ報表
: : 使用單位：﹍﹍﹍﹍﹍﹍﹍﹍﹍﹍
: : 歸屬單位
: : 1 A
: : 2 B
: : 3 D
: : 4 A
: : 我想要在歸屬單位這使用篩選
: : 若我篩選A 我希望使用單位那邊就出現A
: : 趴文都看不太懂 拜託大家幫幫忙
: : ===============================================================
: : 我把我的文件簡單化 弄了兩張圖 請大家幫忙
: : http://picasaweb.google.com/s9009077/NownoF#5359231838850584578
: : 這是原始檔案 已經弄好自動篩選 班級那一欄拉下來應該有
: : 1.叢林1班
: : 2.雨林2班
: : 3.迴旋3班
: : 我希望我拉3. 上面班級後面那個紅框位置也會出現3.
: : 也就是類似這張圖
: : http://picasaweb.google.com/s9009077/NownoF#5359231840910119986
: : 感謝看完的
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 218.164.56.222