作者JieJuen (David)
看板Office
標題Re: [算表] 依成績高低且有條件的排名方法
時間Sun Nov 1 11:01:55 2009
設要達80之科目在A 總分在D
G2 先篩選出達80者之總分
=(A2>=80)*D2
H2 篩選後排名
=RANK(G2,G:G)
I2 "加權"
=(H2<=MIN(10,COUNTIF(A:A,">=80")))*9000+D2
這裡把篩選後排名在10名內的加9000分 (原總分應該不會到9000分吧)
人數不夠就只把達80分的人加9000分
J2 新排名
=RANK(I2,I:I)
http://2y.drivehq.com/q/RankCriteria.xls
以上為四欄法,較簡易
以下陣列公式 以Ctrl+Shift+Enter結尾
(參考
#1Age9WDe 10775 1 9/12 windknife18 R: [算表] 玩:小數進位與排名,排序 )
=SUM(--((SUM(--((A2>=80)*D2<=($A$2:$A$100>=80)*($D$2:$D$100)))<=MIN(10,
COUNTIF(A:A,">=80")))*1000+D2<(MMULT(N(($A$2:$A$100>=80)*$D$2:$D$100<=
TRANSPOSE(($A$2:$A$100>=80)*($D$2:$D$100))),ROW($1:$99)^0)<=MIN(10,
COUNTIF(A:A,"<=80")))*1000+$D$2:$D$100))+1
(N或--隨意用)
若人數不足要從缺請見檔案
I24 在I欄下方加入"從缺分數"
=($J$24="從缺")*(ROW(1:1)<=10-COUNTIF(A:A,">=80"))*9000
即依不夠之人數補上9000分
※ 引述《YoBaby (柚柚)》之銘言:
: 軟體:EXCEL
: 版本:2000
: 如果現在有三項成績,要依總分做最後成績的排名,
: 但是其中一項的成績要達到80分以上才能排進前十名,
: 如果低於80分,就算總分較高也是從第十一名算起,
: 我知道用rank函數可以排名,但是想了很久還是不知道
: 這樣的情況要怎麼寫公式,拜託高手指點一下,謝謝~
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 114.47.38.151
→ YoBaby:非常感謝!!看完恍然大悟啊 希望能變的跟你一樣厲害 11/01 23:22
→ JieJuen:^^ 這是個很有趣的問題 我也因此有些進步呢 11/02 23:20