推 imaltar:t大程式比較精簡 又學到了 我用巨集是想說能讓程式活一點 06/21 15:49
推 haoyunwhite:感謝感謝 這方法好像比較平易近人 i大的則是可以做 06/21 16:06
→ haoyunwhite:比較多的變化 06/21 16:06
題目很有趣
所以我修正一下網友的程式
只要你的資料是符合這樣的格式
(重點是沒有缺失時間的a9701_data a9703_data 如果像這樣有缺失就不適合)
不需要用到巨集
應該都能跑出來
data time;
input change_date a9701_data a9702_data a9703_data a9704_data a9705_data a9706_data
a9707_data a9708_data a9709_data a9710_data a9711_data a9712_data;
cards;
970401 1 0 1 0 4 1 1 0 2 1 3 2
970204 1 1 2 2 0 3 2 2 0 2 1 2
970105 2 1 0 3 2 1 2 0 3 3 0 0
970311 1 0 2 0 3 1 2 3 1 1 1 2
970912 1 2 3 1 0 2 1 1 3 0 2 1
971002 2 1 3 3 2 3 1 2 0 1 2 2
971101 1 2 3 3 0 0 1 1 2 2 3 1
971225 2 2 1 1 3 3 1 2 1 0 2 3
;
run;
data time;
set time;
order=_n_;
run;
proc sort data=time;by change_date order;
run;
proc transpose data=time out=b;by change_date order;
run;
proc sort data=b;by order descending _NAME_;
run;
data b;
set b;
time_0=col1;
time_1=lag(col1);
time_2=lag2(col1);
if order^=lag(order) then time_1=.;
if order^=lag2(order) then time_2=.;
if substr(left(change_date),1,4)=substr(left(_name_),2,4) then output;
keep change_date time_0 -time_2;
run;
※ 引述《imaltar (..)》之銘言：
: ※ 引述《haoyunwhite (毛毛)》之銘言：
: : [軟體程式類別]:
: : SAS
: : [程式問題]:
: : 資料處理
: : [軟體熟悉度]:
: : [問題敘述]:
: : 變數有異動之時間點(change_date)以及各月份的指標 如下面的例子
: : change_date 9701_data 9702_data 9703_data 9704_data 9705_data 9706_data
: : __________________________________________________________________________
: : 970401 1 0 1 0 4 1
: : 970204 1 1 2 2 0 3
: : 想要利用異動時間點判定異動的月份擷取相對應的變數，
: : 也就是說，第一筆資料要抓的是9704_data的值;
: : 第二筆要抓的是9702_data的值。
: : 更進一步要做的是取得異動時間點後面兩個時間點的值，
: : 也就是，第一筆資料要抓的是9705_data以及9706_data的值;
: : 第二筆資料要抓的是9703_data以及9704_data的值;
: : 資料型態變成
: : change_date Time_0 Time_1 Time_2
: : __________________________________________
: : 970401 0 4 1
: : 970204 1 2 2
: : 想法
: : 目前只有想到土法煉鋼的方法
: : if substr(change_date,1,4)=9702 then do;
: : Time_0=9702_data ; Time_1=9703_data ; Time_2=9703_data ; end;
: : else if substr(change_date,1,4)=9706 then do;
: : Time_0=9706_data ; Time_1=9707_data ; Time_2=9708_data ; end;
: : 如果只有一年的資料還好
: : 但是如果延伸至五年，可能程式中月份重複的部分會增加很多
: : 而且未來不一定會只抓後面2期，可能會前後的數值都要擷取，
: : 1.想要請問如果擷取到年月(9706)可以轉而擷取相對應數值的欄位(9706_data)嗎
: : 2.是否有其他的作法，得到相同的結果呢
: : 謝謝大家有耐心看完
: 假設一個資料
: data time;input change_date a9701_data a9702_data a9703_data a9704_data a9705_data a9706_data
: a9707_data a9708_data a9709_data a9710_data a9711_data a9712_data;
: cards;
: 970401 1 0 1 0 4 1 1 0 2 1 3 2
: 970204 1 1 2 2 0 3 2 2 0 2 1 2
: 970105 2 1 0 3 2 1 2 0 3 3 0 0
: 970311 1 0 2 0 3 1 2 3 1 1 1 2
: 970912 1 2 3 1 0 2 1 1 3 0 2 1
: 971002 2 1 3 3 2 3 1 2 0 1 2 2
: 971101 1 2 3 3 0 0 1 1 2 2 3 1
: 971225 2 2 1 1 3 3 1 2 1 0 2 3
: ;
: run;
: 在這邊change_date我是直接用數字型的,因為你下面的程式是根據數字型寫的,
: 如果是日期格式的話,那就要修改
: /****************************************
: indata=原始資料
: start=起始日期(起始月份)
: end=終止日期(終止月份)
: m1=往後觀察的個數(月份)
: m2=往前觀察的個數(月份)
: out=輸出資料
: *****************************************/
: %macro time(indata=,start=,end=,m1=,m2=,out=);
: data &out.;set _null_;
: %do i=&start. %to &end.;
: data temp;set &indata.;if substr(left(change_date),1,4)=&i.;
: if substr(left(change_date),1,4)=&i. then do;Time_0=a&i._data ;
: %do j=1 %to &m1.;
: %if %substr(%eval(&i.+&j.),3,2) <= 12 %then %do;
: Time_&j.=a%eval(&i.+&j.)_data ;
: %end;
: %else %do;
: Time_&j.=.;
: %end;
: %end;
: %do k=1 %to &m2.;
: %if %substr(&i.,3,1)=0 %then %do;
: %if %substr(&i.,4,1)> &k. %then %do;
: Time_bef_&k.=a%eval(&i.-&k.)_data ;
: %end;
: %else %do;
: Time_bef_&k.=.;
: %end;
: %end;
: %else %do;
: %if %substr(&i.,3,2)> &k. %then %do;
: Time_bef_&k.=a%eval(&i.-&k.)_data ;
: %end;
: %else %do;
: Time_bef_&k.=.;
: %end;
: %end;
: %end;
: end;run;
: data &out.;set &out. temp(keep=change_date Time_0 Time_1-Time_&m1. Time_bef_1-Time_bef_&m2.);run;
: %end;
: %mend;
: %time(indata=time,start=9711,end=9712,m1=3,m2=4,out=out);
: 不過這只能抓一年的資料,如果跨年度,例如97年11月,想向後追蹤3個月,只能抓到12月
: 而已,除非change_date改成日期格式,才能調整%macro成可以跨年度去追蹤
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 134.208.29.183