Re: [VBA ]將varchar數值'true'轉換成資料型別為bi …

[fumizuki (矇面加菲獅)]

Function AccessValues(ParamArray Values() As Variant) As String

    Dim Value As Variant, output As String
    Dim vt As VbVarType
    For Each Value In Values
        If output <> "" Then output = output & ","
        vt = VarType(Value)
        If vt = vbBoolean Then
            '布林值(是/否) 轉換成 1 或 0
            If Value Then Value = "1" Else Value = "0"
        ElseIf vt = vbString Then
            '字串將字串中的雙引號轉換成 2 個雙引號，並於頭尾加上雙引號
            'Access 是用雙引號當字串識別符號，SQL Server 是單引號
            Value = Chr(34) & Replace(Value, Chr(34), Chr(34) & Chr(34)) & _
                    Chr(34)
        ElseIf vt = vbInteger Or vt = vbLong Or vt = vbSingle Or _
            vt = vbDouble Or vt = vbCurrency Or vt = vbDecimal Then
            '數字不需要任何處理
        ElseIf vt = vbDate Then
            '日期
            Value = Chr(34) & Format(Value, "yyyy/mm/dd hh:mm:ss") & Chr(34)
        ElseIf vt = vbNull Then
            'Null 值
            Value = "Null"
        Else
            Err.Raise 13 '型態不符
        End If
        output = output & Value
    Next
    AccessValues = output

End Function


'''

CurrentProject.Connection.Execute "insert into 訂購檢驗一覽表 " & _
"(檢驗日期,料號檢驗者,OK,NG) values (" & _
AccessValues(rst.Fields("檢驗日期").Value, rst.Fields("料號").Value, _
rst.Fields("檢驗者").Value, rst.Fields("OK").Value, _
rst.Fields("NG").Value) & ")"

--
                                ▃▅▇▆▄                         ▆▂▃  `  
逝去感情如何能留住，半點癡情遺留殊不易，██▅▇▄▃                ▇▃▂"  .
                                    █████████▃i              ▁▄▇ 
              更多悽悽慘慘的遭遇…………██▆▃                █▅▆▃ˍ▄* 
                                                 ◢           ▂█▄▇▅▂▌. 
我不知道，王～八～蛋～～！           ▂▆███    █▄▃  。fumizuki。Check。

--
※ 發信站: 批踢踢實業坊(ptt.cc) 
◆ From: 123.194.100.4
推 mindscold:感謝版大…但小女子真的不懂為何2張表的欄位型態一樣
→ mindscold:卻還要多做一次型態轉換的動作？
推 fumizuki:不是型態的問題 是sql命令要用1和0表示布林值
推 fumizuki:vb會用True和False來表示布林值