→ Senkousha:在本板搜尋"static", 有另外的好文 :) 04/06 02:04
推 yhn0tgb60:好詳細阿 太感謝你了 這篇該M 謝謝了 ^^ 04/06 02:04
※ 引述《yhn0tgb60 (呦厚厚)》之銘言：
: 就是最近在建一個自己在使用的 library
: 主要是希望 之後寫程式可以方便一點
: 不過最近再思考一個問題
: 就是在 library 裡面的 function 什麼時候會用 static ???
: 像 flash 內建的 library
: 有些是要 new了後才能用 有些則是 static的 直接就可以用
: 想請問 通常怎麼的 function 會設計成需要 new ???
如果是描述"個體"行為 的function 通常會作成 member function:
class Human { ... }
var man1 : Human = new Human();
var man2 : Human = new Human();
var woman1 : Human = new Human();
man1.walkAway();
man2.walkAway();
woman1.walkAway();
// 註: 三個個體(實體, instance) walk 到哪去, 基本上並不互相影響.
: 而怎樣的 function 會設計成 static ???
static function 通常提供的是"與該 class 相關" 的動作:
Math.max(v1, v2, v3);
// 註: 找出三個數中的最大值, 對"數學"並沒有什麼影響.
: 還有各自有怎樣的優缺點 ???
: 謝謝了 ^^
(public) static function 跟一般 public (member) function
雖然乍看之下沒什麼不同, 但它們其實在本質上就有著一個決定性的差異,
因此將它們相提並論, 比較優缺點會有點奇怪.
這個本質上的不同是什麼呢？
就是 static function 少了一個隱藏的參數: "this".
我們在呼叫 instance method, 也就是 public member function 時,
會需要先 new 出一個某 class 的 instance(實體), 如:
var t : TextField = new TextField();
再透過它呼叫某個函數, 如:
t.addEventListener(Event.ADDED_TO_STAGE, addedHandler);
雖然這個特定的 TextField 物件 t, 並沒有列在傳入 function 的參數當中,
但它卻一定會出現在 function name 的左邊,
因此 flash player 的底層機制就可以知道 function body 中寫到 "this" 時,
指的就是 t。
這也就是為什麼, 如果我們在實作 static function 誤用了 "this" 這個關鍵字,
會看到這樣的錯誤訊息: The "this" keyword cannot be used in static methods.
因為我們呼叫 static function 時, 左邊寫的只是 class 的名稱而已:
Math.max(v1, v2, v3);
所以說, 當 function 內部需要用到 "this" 這個關鍵字時,
就非宣告為 non-static 不行了.
看到這裡應該有人會想說：咦？我好像一輩子都沒用過什麼 "this" 啊？
這是因為 "this" 實在是太常用了, 所以時常可以省略不寫.
但其實每當我們在 class 中宣告一個非 static 的東西,
而在 function 當中存取它的值的時候, 就不知不覺地用到了 "this":
class SomeDummyClass {
public var myInt : int = 8;
public function getMyInt() : int {
return myInt; // 等同於 return this.myInt;
}
}
簡單地說就是如開頭所言:
如果 function 內部所作的動作, 是需要針對"個體", 改變個體狀態(屬性)的,
通常就會作成 member function:
因為要改變 "這個個體" 的狀態(屬性), 需要透過 "this" 這個參數.
至於 static function, 可以想像成只是為常作的動作提供一個 namespace 所用的.
以上可能寫得有點雜亂, 僅供概念上的參考, 如有錯誤還請不吝指正 :)
下面是一個簡單的例子,
還是不太了解, 或者看了上面文章變得滿頭霧水的板友可以跑起來/改一改參考看看 XD;
package {
import flash.display.Sprite;
public class StaticExample extends Sprite {
public function StaticExample() {
MyDummyClass.staticFunction();
var myDummy : MyDummyClass = new MyDummyClass();
myDummy.memberFunction();
//myDummy.staticFunction(); // 不是這樣用滴.
trace(myDummy.myInt);
//trace(MyDummyClass.myInt) // 不是這樣用滴.
var myDummy2 : MyDummyClass = new MyDummyClass();
myDummy2.myInt += 10;
trace(myDummy.myInt); // 不會被 myDummy2.myInt 影響: 不意外~
trace(myDummy2.myInt);
}
}
} // end of package
class MyDummyClass {
public var myInt : int = 8;
// public static var dummyInt : int = 0; // 試試看改這個?
public static function staticFunction() : void {
trace("in static function!");
//trace(myInt); // 找不到 myInt, 因為 static function 中沒有"this".
//trace(this.myInt); // 不能用 this.
}
public function memberFunction() : void {
trace("in instance method!");
//myInt++;
//this.myInt++;
}
}
--
※ 發信站: 批踢踢實業坊(ptt.cc)
◆ From: 114.45.9.249
※ 編輯: Senkousha 來自: 114.45.9.249 (04/06 02:02)