Re: [算表] 如何從字串中找出特定字串？

[covet (當好男人不當好人)]

軟體:MS Office
版本:2007

        A                       B
1       蘋果 + 香蕉 + 橘子      1
2       柳丁 + 蘋果 + 芭樂      1
3       香蕉 + 芭樂             0
        ....

想要在 A欄找出有「蘋果」的，在 B欄標記為「1」

請問我的程式要怎麼寫呢？

謝謝大家

推 twtimbow: 用FIND()或SEARCH()都可以
→ twtimbow: =IF(ISNUMBER(FIND("蘋果",A2)),1,0)
→ covet:謝謝，我回去試試 :)
如果想要同時找有「蘋果」或「香蕉」任一，請問要怎麼寫？
最後寫法為

=IF(ISNUMBER(FIND("蘋果",A2)),1,=IF(ISNUMBER(FIND("香蕉",A2)),1,0))

再用一個 if 函數去做
想請問有沒有比較便捷的方法呢？

可以用 or 去寫嗎？

謝謝大家
推 JieJuen:6935 #18oZ16vF
> -------------------------------------------------------------------------- <

作者: JieJuen (David) 看板: Office

用OR的寫法改您的式子
=IF(OR(ISNUMBER(FIND("蘋果",A2)),(ISNUMBER(FIND("香蕉",A2)))),1,)

其他寫法
=IF(OR(COUNT(FIND("蘋果",A2)),(COUNT(FIND("香蕉",A2)))),1,)
=IF(COUNT(FIND("蘋果",A2),FIND("香蕉",A2)),1,)
=IF(COUNT(FIND({"蘋果","香蕉"},A2)),1,)
=--(COUNT(FIND({"蘋果","香蕉"},A2))>0)
=COUNT(FIND({"蘋果","香蕉"},A2))>0     →顯示TRUE或FALSE
=COUNT(FIND({"蘋果","香蕉"},A2))       →顯示符合幾種條件

推 covet:謝謝，不過我最後還是用多重 if 下去寫了  囧>
→ JieJuen:XD 等有十個關鍵字時再來用本式好了
※ 重新編輯: JieJuen (09/18/2008)